10 COLOR 15,1,4:CLS:PRINT:PRINT:PRINT:REM REV. 2.1 - 10/27/96
20 PRINT "           MAIN BEAM POWER DENSITY ESTIMATION PROGRAM"
30 PRINT "        FOR ROUTINE EVALUATION OF R.F. SAFETY COMPLIANCE"
40 PRINT:PRINT
50 PRINT "This program uses the formulas given in FCC OET Bulletin No. 65"
60 PRINT "to estimate power density in the main lobe of an antenna, with"
70 PRINT "use of the EPA-recommended ground reflection factor as an option."
80 PRINT:PRINT "This program is intended for far field calculations.  It may"
90 PRINT "overestimate the actual field strength of high-gain antennas in"
100 PRINT "the near field (within several wavelengths of the antenna)."
110 PRINT "However, it may also underestimate the strength of fields that may"
120 PRINT "be encountered in `hot spots' in the near field.  No computer"
130 PRINT "program can predict where wiring or reflective objects may create"
140 PRINT "hot spots in your particular installation.":PRINT
150 PRINT "This is a public domain program by Wayne Overbeck, N6NB":PRINT
160 INPUT "WHAT IS THE AVERAGE POWER AT THE ANTENNA (IN WATTS)"; WATTS
170 PWR = 1000 * WATTS
180 PRINT:PRINT "WHAT IS THE ANTENNA GAIN IN DBI?"
190 INPUT "(Enter 2.2 for dipoles; add 2.2 for antennas rated in DBD): ",GAIN
200 REM NOW CALCULATING EIRP IN MILLIWATTS
210 EIRP = PWR * (10 ^ (GAIN / 10))
220 PRINT:INPUT "WHAT IS THE DISTANCE TO AREA OF INTEREST FROM ANTENNA CENTER IN FEET"; FT
230 REM NOW CONVERTING TO CM
240 DX = FT * 30.48
250 PRINT:INPUT "WHAT IS THE FREQUENCY IN MHZ";F
260 IF F<1.34 THEN STD1=100:STD2=100:GOTO 330
270 IF F<3 THEN STD1=100:STD2=180/((F)^2):GOTO 330
280 IF F<30 THEN STD1=900/((F)^2):STD2=180/((F)^2):GOTO 330
290 IF F<300 THEN STD1=1:STD2=.2:GOTO 330
300 IF F<1500 THEN STD1=F/300:STD2=F/1500:GOTO 330
310 IF F<100000! THEN STD1=5:STD2=1:GOTO 330
320 PRINT "THE FCC DOES NOT HAVE EXPOSURE LIMITS ABOVE 100 GHZ":GOTO 250
330 PRINT:PRINT "NOW, DO YOU WISH TO INCLUDE EFFECTS OF GROUND REFLECTIONS?"
332 PRINT "(Ground effects need not be included in most main-beam calculations"
340 PRINT "but including them may yield more accurate results with very low"
342 PRINT "antennas, non-directional antennas, and calculations below the"
350 INPUT "main lobe of directional antennas.)  INCLUDE GROUND EFFECTS (Y/N)";G$
370 GF=.25:GR$="WITHOUT":IF G$="Y" THEN GF=.64:GR$="WITH"
380 IF G$="y" THEN GF=.64:GR$="WITH"
390 PWRDENS = (GF * EIRP) / (3.14159 * (DX ^ 2))
400 PWRDENS=(INT((PWRDENS*10000)+.5))/10000
410 DX1=SQR((GF*EIRP)/(STD1*3.14159)):DX1=DX1/30.48:DX1=(INT((DX1*10)+.5))/10
420 DX2=SQR((GF*EIRP)/(STD2*3.14159)):DX2=DX2/30.48:DX2=(INT((DX2*10)+.5))/10
430 STD1=(INT((STD1*100)+.5))/100:STD2=(INT((STD2*100)+.5))/100
432 CLS:PRINT "THE RESULTS ARE AS FOLLOWS:":PRINT
440 PRINT "WITH";WATTS;"WATTS AND";GAIN;"DBI GAIN ";GR$;" GROUND REFLECTIONS, AT";FT;"FEET"
450 PRINT "FROM THE ANTENNA CENTER THE ESTIMATED POWER DENSITY IS";PWRDENS;"MW/CM2.":PRINT
460 PRINT "AT";F;"MHZ, THE MAXIMUM PERMISSIBLE EXPOSURE (MPE) IN `CONTROLLED"
470 PRINT "ENVIRONMENTS' (SUCH AS YOUR OWN HOUSEHOLD OR CAR) IS"; STD1; "MW/CM2."
480 PRINT "THE MPE IN `UNCONTROLLED ENVIRONMENTS' (SUCH AS NEIGHBORS' PROPERTY)"
490 PRINT "IS"; STD2; "MW/CM2.  THIS INSTALLATION WOULD MEET THE CONTROLLED MPE"
500 PRINT "LIMIT AT";DX1;"FEET AND THE UNCONTROLLED LIMIT AT";DX2;"FEET."
510 PRINT:PRINT "ALTERNATE CALCULATION METHODS:"
520 PRINT "   1) Exposure is averaged over six minutes in controlled environments"
530 PRINT "and 30 minutes in uncontrolled environments.  If you never transmit more"
540 PRINT "than three minutes in any six-minute period, divide the power density"
550 PRINT "shown above by two when calculating the power density in your own house-"
560 PRINT "hold.  Also divide by two when calculating fields beyond your property"
570 PRINT "if you never transmit more than 15 minutes in any 30-minute period."
580 PRINT "   2) If you wish to estimate the power density at a point below the main"
590 PRINT "lobe of a directional antenna, and if the antenna's vertical pattern is"
600 PRINT "known, recalculate using the antenna's gain in the relevant direction."